How to recenter the *compilation* buffer (on C-c C-x)? No process for this document

Question

I have a .tex/.Rnw document which is compiled with a makefile. During the compilation, I would like to use C-c C-l (as for standard .tex files) to recenter the output buffer so that I can follow it. However, this gives me (Emacs 24, Ubuntu 12.10): No process for this document. I'd guess this is because there is no association with LaTeX anymore (make could do anything). The output buffer is called *compilation*, so if one could define C-c C-l to recenter this output buffer, that would solve it.

Answer 1

Okay, I looked at TeX-recenter-output-buffer and adjusted it accordingly (I'm not an elisp programmer, so... use with care).

;; recenter *compilation* buffer (adjusted from TeX-recenter-output-buffer)
(defun compile-recenter-output-buffer (line)
  "Redisplay *compilation* buffer of compile job output so that most recent
output can be seen. The last line of the buffer is displayed on line LINE
of the window, or at bottom if LINE is nil."
  (interactive "P")
  (let ((buffer (get-buffer "*compilation*"))); adjusted
    (if buffer
    (let ((old-buffer (current-buffer)))
      (pop-to-buffer buffer t t); adjusted
      (bury-buffer buffer)
      (goto-char (point-max))
      (recenter (if line
            (prefix-numeric-value line)
              (/ (window-height) 2)))
      (pop-to-buffer old-buffer nil t)); adjusted
      (message "No *compilation* buffer found."))))

I then bound it to C-c o via (global-set-key (kbd "C-c o") 'compile-recenter-output-buffer).

Answer 2

You could define a custom application of the tex-recenter-output-buffer function:

(defun recenter-compilation-buffer (linenum)
  (interactive "P")
  (let ((compilation-buffer (get-buffer "*compilation*"))
        (window))
    (if (null compilation-buffer)
       (message "No compilation buffer")
      (setq window (display-buffer compilation-buffer))
      (save-selected-window
         (select-window window)
         (bury-buffer compilation-buffer)
         (goto-char (point-max))
         (recenter (if linenum
                   (prefix-numeric-value linenum)
                (/ (window-height) 2)))))))

Then, add it as a hook to LaTeX mode:

(add-hook 'tex-mode-hook
        '(lambda ()
           (local-set-key "\C-c\C-l" 'recenter-compilation-buffer)))

Answer 3

I assume you are invoking compile rather than using AUCTeX. This completely bypasses AUCTeX as you have guessed. The way to use AUCTeX is to add the following to your .emacs.

(add-to-list 'TeX-command-list
 ("Make"               ;; The command you use to invoke it: C-c C-c Make RET
  "make pdf"           ;; The make command to run
  TeX-run-TeX nil t    ;; TeX-run-TeX tells it to parse error as if from TeX
  :help "Run make to build everything")

Doing things this way has the added advantage of allowing AUCTeX to parse the errors. If your make file emits compiler type errors then you can change TeX-run-TeX to TeX-run-compile and it will run in a compilation mode buffer. See the documentation for other options.