Year in bibliography with brackets

Question

i want in my bibliography the year within brackets. How can I customize my style?

I think I have to change the FUNCTION {format.date}, but how?

regards

\documentclass[pdftex,a4paper,12pt,german]{book}
\usepackage[german,ngerman]{babel} 
\usepackage[latin1]{inputenc}
\usepackage[T1]{fontenc}
\usepackage[authoryear]{natbib}
\begin{document}
\bibliographystyle{myplainnat}
\cite{Alonso.2004}
\bibliography{Literatur}
\end{document}

@book{Alonso.2004,
 author = {Alonso, Gustavo and Casati, Fabio and Kuno, Harumi and Machiraju, Vijay},
 year = {2004},
 title = {Web services: Concepts, architectures and applications},
 url = {http://www.loc.gov/catdir/enhancements/fy0817/2004298168-d.html},
 address = {Berlin},
 publisher = {Springer},
 isbn = {3540440089},
 series = {Data-centric systems and applications}
}

Now my bibliography looks like this:

G. Alonso, F. Casati, H. Kuno, and V. Machiraju. 2004, Web services: Concepts, architectures and applications. Data-centric systems and applications. Springer, Berlin, 2004.

But I want it looks like this:

G. Alonso, F. Casati, H. Kuno, and V. Machiraju. (2004), Web services: Concepts, architectures and applications. Data-centric systems and applications. Springer, Berlin, 2004.

The First Year within brackets

Answer 1

You did not provide your bibliography style, but it should work like this: add the two lines to format.date as

FUNCTION {format.date}
{ year duplicate$ empty$
    { "empty year in " cite$ * warning$
       pop$ "" }
    'skip$
  if$
  month empty$
    'skip$
    { month
      " " * swap$ *
    }
  if$
  duplicate$ empty$ 'skip$ %% added
  { "(" swap$ * ")" *}     %% added
  if$
  extra.label *
}

To have a period in front of the year instead of the comma, issue a new.block command before the output of the year, like I did here for the article type

FUNCTION {article}
{ output.bibitem
  format.authors "author" output.check
  author format.key output
  new.block
  format.title "title" output.check
  new.block
  crossref missing$
    { journal emphasize "journal" output.check
      eid empty$
        { format.vol.num.pages output }
        { format.vol.num.eid output }
      if$
      new.block                        %% added
      format.date "year" output.check
    }
    { format.article.crossref output.nonnull
      eid empty$
        { format.pages output }
        { format.eid output }
      if$
    }
  if$
  format.issn output
  format.doi output
  format.url output
  new.block
  note output
  fin.entry
}

Answer 2

Fix the address year problem with another customized formate.date Function

  FUNCTION {format.dateWithSpace}
    { year duplicate$ empty$
        { "empty year in " cite$ * warning$
           pop$ "" }
        'skip$
      if$
      month empty$
        'skip$
        { month
          " " * swap$ *
        }
      if$                                   
      duplicate$ empty$ 'skip$              %% added
      { " " swap$ * "" *}                   %% added
      if$
      extra.label *
    }