Errors with Asymptote

Question

I am trying to draw a simple tetrahedron with the following code (in Asymptote)

size(10cm,0);
import math;
import three;
import graph3;
currentprojection=perspective(1/3,-1,1/2);

real l2=sqrt(0.75);
triple x1=(0,0,0), x2=(1,0,0), x3=(0.5,l2,0);
draw(x1--x2--x3--cycle);
label("$x_1$",x1,W);
label("$x_2$",x2,E);
label("$x_3$",x3,NW);
dot(x1);dot(x2);dot(x3);

triple b3=(0.5,l2/2,0);
dot(b3,red);
label("$B_3$",b3,S,red);

real l3=sqrt( (5+4*l2*l2)/9 );
triple x4=(0.5,l2/2,l3);
draw(b3--x4,red);
label("$x_4$",x4,N,red);

draw(x4--x1,dashed);
draw(x4--x2,dashed);
draw(x4--x3,dashed);

Compiling with asy tetrahedron.asy gives me an eps image in which the line x1--x2 is dashed for some reason, and compiling with asy tetrahedron.asy -tex pdflatex gives me a blank image. tex.SE doesn't allow me to upload images in either format, but I can share them with any other tool that users may request. Just post a comment with the tool I should use.

Any help would be greatly appreciated, to understand why I'm getting these errors, and/or how I could fix my script.

Answer 1

The line is not dashed, it's just rendered like that. With the three module, Asymptote produces raster output rather than vector output. You can increase the resolution (and slow down the time it takes to do the rendering) with the -render option. The default value is 2 for eps output. Your drawing looks better on my system, if I turn the viewing angle slightly and compile with asy -render 7. Here it is using

currentprojection=perspective(1,-1,1/2);

and converted using OSX Preview to png at 142 pixels per inch.

If you would rather have proper vector output, then you should probably use pstricks, which does 3D very well (although most of the documentation is only in French). Metapost is another alternative that produces vector PostScript but there's no standard approach to 3D. You could try mp3d or mp-solid, but for something as simple as your tetrahedron however all you need is a routine to project a 3D point to a 2D one. Like this:

prologues := 3;
outputtemplate := "%j%c.eps";

vardef pp(expr xx,yy,zz) = 
  _x := yy*cosd(theta) - xx*sind(theta);
  _y := zz*cosd(phi) - yy*sind(theta)*sind(phi) - xx*cosd(theta)*sind(phi);
  _z := 12 - zz*sind(phi) - yy*sind(theta)*cosd(phi) - xx*cosd(theta)*cosd(phi);
  1000*(_x/_z, _y/_z)
enddef;

theta := 288; % rotation of viewpoint
phi := 18;    % elevation of viewpoint

beginfig(1);

z0 = pp(0,0,0);
z1 = pp(-sqrt(3)/2, -1/2, 0);
z2 = pp(+sqrt(3)/2, -1/2, 0);
z3 = pp(0,1,0);
z4 = pp(0,0,sqrt(2));

draw z1--z2--z3--cycle;
draw z0 -- z4 withcolor .67 red;
draw z1 -- z4 dashed evenly scaled .7;
draw z2 -- z4 dashed evenly scaled .7;
draw z3 -- z4 dashed evenly scaled .7;

dotlabel.lft (btex $x_1$ etex, z1);
dotlabel.rt  (btex $x_2$ etex, z2);
dotlabel.ulft(btex $x_3$ etex scaled .8, z3);
dotlabel.top (btex $x_4$ etex, z4);
dotlabel.rt  (btex $B_3$ etex, z0) withcolor .67 red;

endfig;
end.

The advantages are (a) it's very simple and fast and (b) it's proper vector output, so there are no jagged edges. But that's about it; PSTricks or Asymptote will do a better job at more or less every other aspect of 3D drawing.

Answer 2

According to the documentation of Asymptote, you have 3 (or 4) different ways to deal with the 3D

• PRC : pdf output, only supported by Adobe Reader. Moreover the 3D picture is interactive through Adobe Reader.
• OpenGL based renderer : -V option. An OpenGL window is opened with your 3D scene, interactive manipulation (changing the point of view, show camera), export (bitmap)
• with the previous OpenGL renderer, -render=n n pixels per bitmap, png, pdf, eps output. Some problems occurs with some opengl drivers/graphic cards (like vertical lines)
• render=0 : the very old 3D mode of Asymptote. Only a 2D projection of the 3D scene, no algorithm to deal with hidden faces. But vectorized output

For such an example or a very simple 3D scene for which you can manage by yourself hidden faces, dashed segments, asy -render=0 gives a vectorised output. Of course -render=0 is very limited for 3D (I remember some asy package for solids to manage dashed/not dashed segment with respect to the camera).