Asymptote 3D label background

Question

I'd like to create a 3D label in Asymptote that has a "background," effectively giving the label the look as though it were printed on poster board. I don't care if this background conforms to the Billboard effect when the 3D image is rotated; my only need here is for a static picture. I need the label to stand out against the surface behind it.

I know I could fake it by placing a white plane behind my label, but I don't know how to form this plane properly - how to correctly find the normal of the plane so that it looks rectangular from the viewpoint.

Here's a MWE, wherein the text of the label gets a little "lost" in the lines of the surface behind it.

import graph3;
size(200,200,IgnoreAspect);
currentprojection=orthographic(5,5,1);
defaultrender.merge=true;

triple f(pair t) {
    return (t.y*cos(t.x),2*t.y*sin(t.x),t.y);//
}
surface s=surface(f,(0,0),(2*pi,2),32,32,Spline);
draw(s,emissive(white),meshpen=black+.2mm);

label("plot of $x$",(2,2,1.5));

I use TikZ for some of my graphics, and there it is a simple manner to have the node drawn with a solid background color making the text easy to read. I am basically looking for the same effect here.

Answer 1

The following solution is slightly hacky, but much less draconian than drawing on top of the picture. It creates two labels: one with the text, and one, positioned directly behind the text (relative to the camera), with a solid box the same size as the text. This solution will only work if the projection is orthographic.

settings.outformat="png";
settings.render=4;
import graph3;
usepackage("color");
size(200,200,IgnoreAspect);
currentprojection=orthographic(5,5,1);

// Decreasing the tubegranularity makes the gridlines look nicer.
defaultrender.tubegranularity = 1e-3;

triple forward = -unit(currentprojection.camera);
// Take the component of currentprojection.up orthogonal to forward.
triple upvec = unit(currentprojection.up - dot(currentprojection.up,forward) * forward);
triple rightvec = cross(forward, upvec);

triple f(pair t) {
    return (t.y*cos(t.x),2*t.y*sin(t.x),t.y);
}
surface s=surface(f,(0,0),(2*pi,2),32,32,Spline);
draw(s,emissive(white),meshpen=black+.2mm);

label("plot of $x$", (2,2,1.5));
label("\colorbox{black}{plot of $x$}", (2,2,1.5) + .01 forward, white+opacity(0.9));

Answer 2

Following the answer from asymptote discussion,

//
// bglabel3d.asy
//
settings.tex="pdflatex";
settings.prc=false;
settings.render=0;

import graph3;
size(200,200,IgnoreAspect);
currentprojection=orthographic(5,5,1);
defaultrender.merge=true;

triple f(pair t) { return (t.y*cos(t.x),2*t.y*sin(t.x),t.y); }

surface s=surface(f,(0,0),(2*pi,2),32,32,Spline);
draw(s,emissive(white),meshpen=deepblue+.2mm);

label(Label("plot of $x$",Fill(orange+opacity(0.8))),(2,2,1.5));

Edit:

As it is noted in the linked answer, this solution works only with render=0.

For raster images we can draw the labels on the image:

First, make a label-free img.png:

//
// scene3d.asy
//
settings.outformat="png";
settings.prc=false;
settings.render=4;
import graph3;
size(200,200,IgnoreAspect);
currentprojection=orthographic(5,5,1);
defaultrender.merge=true;

triple f(pair t) { return (t.y*cos(t.x),2*t.y*sin(t.x),t.y); }

surface s=surface(f,(0,0),(2*pi,2),32,32,Spline);

pen bpen=rgb(0.75, 0.7, 0.1);
material m=material(diffusepen=0.6bpen
  ,ambientpen=bpen
  ,emissivepen=0.4*bpen
  ,specularpen=0.8white
  ,shininess=1.0);
draw(s,m);
shipout("img");

next, draw the labels on the raster image:

settings.tex="pdflatex";
import graph;
import math; // for grid() function

defaultpen(fontsize(10pt));

real sc=1/4;
unitsize(sc*1bp);

real wd=796*sc;
real ht=808*sc;

label(
  shift(wd/2,ht/2)*
  graphic("img.png"
  ,"width="+string(wd)+"bp"
  +",height="+string(ht)+"bp"
  +",scale="+string(sc)
  ),(0,0)
);
layer();

draw(((0,0)--(wd,ht)/sc),blue+2pt);

int ngrid=100;
int n=(int)(wd/(ngrid-1)/sc);
int m=(int)(ht/(ngrid-1)/sc);
add(scale(ngrid)*grid(n,m,yellow));

xaxis( 0,wd/sc,RightTicks(Step=ngrid));
yaxis(0,ht/sc,LeftTicks(Step=ngrid));


label(Label("plot of $y$"
    ,Fill(1mm,orange+opacity(0.8))),(400,400));