Here's a Metapost alternative. Compile with lualatex
.

\RequirePackage{luatex85}
\documentclass[border=5mm]{standalone}
\usepackage{luamplib}
\begin{document}
\mplibtextextlabel{enable}
\begin{mplibcode}
beginfig(1);
path C;
C = fullcircle scaled 144;
pair M;
M = point 1.1 of C;
draw C;
draw point 0 of C -- point 4 of C;
draw point 2 of C -- point 6 of C;
draw origin -- M;
draw point 4 of C -- M;
vardef angle_label(expr a,b,c,r,s) =
save arc; path arc;
arc = fullcircle scaled r
rotated angle (a-b)
shifted b
cutafter (b--c);
draw arc withpen pencircle scaled 1/4;
label(s,point 1/2 of arc shifted -b scaled (1+10/r) shifted b);
enddef;
angle_label(point 0 of C, point 4 of C, M, 45, textext("$t$"));
angle_label(point 0 of C, origin, M, 30, textext("$\theta$"));
label.rt ("$(1,0)$", point 0 of C);
label.top("$(0,1)$", point 2 of C);
label.lft("$(-1,0)$", point 4 of C);
label.bot("$(0,-1)$", point 6 of C);
dotlabel.urt("$M$", M);
endfig;
\end{mplibcode}
\end{document}
And if you prefer the charming hand-drawn look of the original, you could load the "Euler" font, use a bit of colour, and draw the lines "freehand" with an extra macro.

\RequirePackage{luatex85}
\documentclass[border=5mm]{standalone}
\usepackage{luamplib}
\usepackage{euler}
\begin{document}
\mplibtextextlabel{enable}
\begin{mplibcode}
% freehand - draw a bit wobbly
newinternal freehand_randomness;
newinternal freehand_overshoot;
freehand_randomness := 2;
freehand_overshoot := 4;
vardef freehand expr p =
if path p:
if cycle p:
for t=0 upto length p - 1:
point t of p
{ direction t of p rotated (freehand_randomness*normaldeviate) }
..
endfor cycle
else:
-freehand_overshoot*unitvector(direction 0 of p) shifted point 0 of p ..
for t=0 upto length p:
point t of p
{ direction t of p rotated (freehand_randomness*normaldeviate) }
..
endfor
+freehand_overshoot*unitvector(direction length p of p) shifted point length p of p
fi
fi
enddef;
% mark angle labels
vardef angle_label(expr a,b,c,r,s) =
save arc; path arc;
arc = fullcircle scaled r
rotated angle (a-b)
shifted b
cutafter (b--c);
draw arc withpen pencircle scaled 1/4 withcolor 3/4 red;
label(s,point arctime 1/2 arclength arc of arc of arc shifted -b scaled (1+10/r) shifted b);
enddef;
beginfig(1);
path C;
C = fullcircle scaled 144;
pair M;
M = point 1.1 of C;
draw C;
draw freehand point 0 of C -- origin -- point 4 of C;
draw freehand point 2 of C -- origin -- point 6 of C;
draw freehand origin -- M;
draw freehand point 4 of C -- M;
angle_label(point 0 of C, point 4 of C, M, 45, textext("$t$"));
angle_label(point 0 of C, origin, M, 30, textext("$\theta$"));
labeloffset := 8;
dotlabel.urt("$M$", M);
drawoptions(withcolor 2/3 blue);
label.rt ("$(1,0)$", point 0 of C);
label.top("$(0,1)$", point 2 of C);
label.lft("$(-1,0)$", point 4 of C);
label.bot("$(0,-1)$", point 6 of C);
drawoptions();
endfig;
\end{mplibcode}
\end{document}