How to cross-reference to a specific label with RefTeX

Question

In LaTeX, the labels are defined as \label{eq:1}. When you want to reference to that equation, you could easily search all \label in the document by C-c ) and that command insert reference to that label \ref{eq:1}

Currently I am using a special language in which every labels are in the form label{eq:1} and the references ref{eq:1}(no backslash). So I wonder how I could customize RefTeX to search label and insert ref for a chosen label.

Answer 1

RefTeX stores regexps matching \label definitions in reftex-label-regexps; you have to customize it in order to match label without a \. You can make the \ optional by putting it inside a shy group.

Then you have to write some code to run the functions reftex-reference and reftex-label with the second optional NO-INSERT argument and bind the functions to some key strokes. Putting something like this in your .emacs should do the trick:

(add-hook 'reftex-mode-hook
          (lambda ()
            ;; do this all only once
            (unless (member
                     "\\(?:\\\\\\)?label{\\(?1:[^}]*\\)}"
                     reftex-label-regexps)
              ;; label stuff
              (setq reftex-label-regexps
                    '("\\(?:\\\\\\)?label{\\(?1:[^}]*\\)}"
                      "\\[[^][]\\{0,2000\\}\\<label[[:space:]]*=\[[:space:]]*\
{?\\(?1:[^],}]+\\)}?"))
              (reftex-compile-variables)
              (defun doconce-label ()
                (interactive)
                (insert "label{" (reftex-label nil t) "}"))
              (local-set-key (kbd "C-c l") #'doconce-label)
              ;; ref stuff
              (defun doconce-ref ()
                (interactive)
                (insert "ref{" (reftex-reference nil t) "}"))
              (local-set-key (kbd "C-c r") #'doconce-ref))))