0

How can I plot following figure without the airplane? $l_1$ on the left and right are in the same line, so is $l_2$. Many thanks for your help!

enter image description here

closed as too broad by Schweinebacke, Franck Pastor, marmot, Zarko, Rmano Dec 24 '17 at 16:08

Please edit the question to limit it to a specific problem with enough detail to identify an adequate answer. Avoid asking multiple distinct questions at once. See the How to Ask page for help clarifying this question. If this question can be reworded to fit the rules in the help center, please edit the question.

  • 2
    That's mostly just some straight lines, have you tried anything? – Torbjørn T. Dec 24 '17 at 10:03
  • 2
    Questions that look like "Please do this complicated thing for me" tend to get closed because they are "too localized" or "too broad". Please try to make your question clear and simple by giving a minimal working example (MWE) showing your effort in solving the problem: you'll stand a greater chance of getting help. – Schweinebacke Dec 24 '17 at 12:02
  • 2
    Such a nice nickname choice for a do-it-for-me :) Any Tesla's around? – percusse Dec 24 '17 at 13:29
8

I know you've tagged this tikz-pgf, but since there are plenty of TikZ tutorials, here is a commented version in Metapost which is an alternative drawing tool that you might like to learn.

Compile this with lualatex (or work out how to adapt it for plain Metapost, or GMP).

enter image description here

One generally useful thing shown here is how to do the equivalent of a TikZ scope shift in Metapost, by shifting the currentpicture variable half way through.

\RequirePackage{luatex85}
\documentclass[border=5mm]{standalone}
\usepackage{luamplib}
\begin{document}
\mplibtextextlabel{enable}
\begin{mplibcode}
beginfig(1);
    % first make useful star shaped path
    path pentagram; pentagram = for t=0 upto 4: up rotated 144 t -- endfor cycle; 

    % now make a drawing with the common parts
    picture base;
    base = image(
        % define the four lines...
        path a, b, c, d;  
        a = (left -- right) scaled 80;                
        b = a shifted 48 up;
        c = (down -- 3 up) scaled 16 shifted 60 left;
        d = (down -- 3 up) scaled 16 shifted 60 right;

        % draw the lines...
        draw a withcolor 1/2 white; 
        draw b withcolor 1/2 white;

        drawoptions(withcolor 1/2 [blue, white]);
        draw c dashed evenly scaled 1/2;
        draw d dashed evenly scaled 1/2;

        % add some decorations
        drawoptions(withcolor 1/4 [blue, white]);
        drawarrow point 0 of c -- point 0 of d;
        fill pentagram scaled 4 shifted (a intersectionpoint c);
        fill pentagram scaled 4 shifted point 1 of d;
        drawoptions();

        % add some labels to the lines
        label.rt("$l_1$", point 1 of a);
        label.rt("$l_2$", point 1 of b);
        label.bot("$u$",  point 0 of c);
        label.bot("$v$",  point 0 of d);
    );

    % now draw the base image, and add the track
    % slightly shortened so it looks better with the markers
    draw base;
    drawarrow ((-60,0) -- (-30, 48) -- (60, 48)) 
        cutbefore fullcircle scaled 10 shifted (-60,0)
        cutafter  fullcircle scaled 10 shifted (60,48)
        dashed evenly 
        withpen pencircle scaled 1 
        withcolor red;

    % shift the whole picture 200 to the left
    currentpicture := currentpicture shifted 200 left;

    % and draw the base again, but with a different track and a label
    draw base;
    drawarrow ((-60,0) -- (-30, 0) -- (0, 48) -- (60, 48)) 
        cutbefore fullcircle scaled 10 shifted (-60,0)
        cutafter  fullcircle scaled 10 shifted (60,48)
        dashed evenly 
        withpen pencircle scaled 1 
        withcolor red;
    dotlabel.bot("$A$", (-30,0));

endfig;
\end{mplibcode}
\end{document}

Not the answer you're looking for? Browse other questions tagged or ask your own question.