Change connector from "and" to "," in 'author' field, IEEEtranN bibliography style

Question

I'm using Natbib and I'm trying to make the authors in my bibliography appear like

Bryan Sullivan, Vincent Liu

but at the moment they appears like

Bryan Sullivan and Vincent Liu

I have tried using

\renewcommand{\multinamedelim}{\addsemicolon\space}

but it's not working, it says that \multinamedelim doesn't exist.

I'm adding bibliography as so:

@book {
    WebApplicationSecurity,
    author = {{Bryan Sullivan} and {Vincent Liu}},
    title = {Web Application Security, a Beginner's Guide},
    publisher = {McGraw Hill},
    year = {2011}
}

I have also tried changing the "and" in this code to a comma, but then the second author disappears completely.

I'm compiling with XeLaTeX. Any help would be appreciated

Answer 1

OK, I'm new to this (~1yr new to LaTeX, even newer bst) so please be kind, but I think I've got it:

Modify IEEEtranN.bst such that FUNCTION {format.names} reads:

FUNCTION {format.names}
{ 'bibinfo :=
  duplicate$ empty$ 'skip$ {
  this.to.prev.status
  this.status.std
  's :=
  "" 't :=
  #1 'nameptr :=
  s num.names$ 'numnames :=
  numnames 'namesleft :=
    { namesleft #0 > }
    { s nameptr
      name.format.string
      format.name$
      bibinfo bibinfo.check
      't :=
      nameptr #1 >
        { nameptr num.names.shown.with.forced.et.al #1 + =
          numnames max.num.names.before.forced.et.al >
          is.forced.et.al and and
            { "others" 't :=
              #1 'namesleft :=
            }
            { skip$ }
          if$
          namesleft #1 >
            { ", " * t do.name.latex.cmd * }
            { s nameptr "{ll}" format.name$ duplicate$ "others" =
                { 't := }
                { pop$ }
              if$
              t "others" =
                { " " * bbl.etal emphasize * }
                { numnames #2 >
                    { "," * }
                    { "," * } %%%%%%%%%%%%% added this line
                    %{ skip$ } %%%%%%%%%%%%% commented out this line
                  if$
                  %bbl.and %%%%%%%%%%%%% commented out this line
                  space.word * t do.name.latex.cmd *
                }
              if$
            }
          if$
        }
        { t do.name.latex.cmd }
      if$
      nameptr #1 + 'nameptr :=
      namesleft #1 - 'namesleft :=
    }
  while$
  cap.status.std
  } if$
}

This should change the name formatting, as shown below, for all types. Hope that helps!

Edit: if you want the in text reference formatting to change as well as the bibliography formatting, follow the answer by @Mico : https://tex.stackexchange.com/a/506121/169285 (with a word of caution - it will also change 'format.lab.names' and I'm not entirely sure what this does).

Edit 2: MWE:

\documentclass{article}
\usepackage{natbib}

\begin{document}

Stuff happened \cite{WebApplicationSecurity}.

\newpage
\bibliographystyle{IEEEtranN}
\bibliography{mybib.bib}

\end{document}