Opacity in Asymptote

Question

Consider a MWE:

This is part of some diagram, so it looks unfinished, but never mind. I tried to make the example really minimal working.

\documentclass{article}%
%============================================================
\usepackage{asymptote}
\usepackage[utf8]{inputenc}
\usepackage{color}
%============================================================
\begin{document}
\begin{asy}
settings.outformat = "pdf";
settings.prc = false;
settings.render = 16;
import three;
import bsp;
texpreamble("\usepackage{euler,beton}");
size(5cm, 0);
currentprojection=orthographic((5,4,3));

path3 pl =plane((0,-2,0),(-2,0,0),(0,1,0));
path3 pl1=rotate(-28,X)*pl;
path3 pl2=rotate(-56,X)*pl;
path3 pl3=shift(-0.3*normal(pl1))*pl1;

triple[] asd=intersectionpoints(pl2,pl3);
triple A=asd[1];
triple B=asd[0];

triple[] asf=intersectionpoints(pl,pl2);
triple C=asf[1];
triple D=asf[0];

triple[] asg=intersectionpoints(pl,pl3);
triple E=asg[1];
triple F=asg[0];

path3 q11=(D -- -Y -- C-Y -- C -- cycle);
surface sq11=surface(q11);
draw(sq11,white+opacity(.6),light=nolight);
draw(D -- -Y -- C-Y -- C--cycle);

path3 q31=(D--C--A--B--cycle);
surface sq31=surface(q31);
draw(sq31,white+opacity(.6),light=nolight);
draw(D--C--A--B--cycle);

\end{asy}

\end{document}

It works. BUT I want it to be vector graphics (publishing house requirement). When I change

settings.render = 16;

into

settings.render = 0;

('cause that's what makes my graphics vector ) it brakes:

If I keep it vector (settings.render = 0;), but comment all the lines with opacity options, it works:

but this is not what I want.

How to make a vector picture with opacity option for these planes?

Commented example for your comvenience:

\documentclass{article}%
%============================================================
\usepackage{asymptote}
\usepackage[utf8]{inputenc}
\usepackage{color}
%============================================================
\begin{document}
\begin{asy}
settings.outformat = "pdf";
settings.prc = false;
settings.render = 0;
import three;
import bsp;
texpreamble("\usepackage{euler,beton}");
size(5cm, 0);
currentprojection=orthographic((5,4,3));

path3 pl =plane((0,-2,0),(-2,0,0),(0,1,0));
path3 pl1=rotate(-28,X)*pl;
path3 pl2=rotate(-56,X)*pl;
path3 pl3=shift(-0.3*normal(pl1))*pl1;

triple[] asd=intersectionpoints(pl2,pl3);
triple A=asd[1];
triple B=asd[0];

triple[] asf=intersectionpoints(pl,pl2);
triple C=asf[1];
triple D=asf[0];

triple[] asg=intersectionpoints(pl,pl3);
triple E=asg[1];
triple F=asg[0];

path3 q11=(D -- -Y -- C-Y -- C -- cycle);
surface sq11=surface(q11);
//draw(sq11,white+opacity(.6),light=nolight);
draw(D -- -Y -- C-Y -- C--cycle);

path3 q31=(D--C--A--B--cycle);
surface sq31=surface(q31);
//draw(sq31,white+opacity(.6),light=nolight);
draw(D--C--A--B--cycle);

\end{asy}

\end{document}

For references: this is a continuation of my question.

Answer 1

I do not know if this example was ok with a previous version of Asymptote or/and Ghostscript. It seems that transparency, render=0 and surface cannot work all together.

However there is a difference with the example in Planes' intersection in Asymptote. In this example you use the bsp package and transparency, render=0, bsp can work all together. Your MWE it becomes

      settings.outformat = "pdf";
      settings.prc = false;
      settings.render = 0;
      import three;
      import bsp;
      texpreamble("\usepackage{euler,beton}");
      size(10cm);


      currentprojection=orthographic((5,4,3));

      path3 pl =plane((0,-2,0),(-2,0,0),(0,1,0));
      path3 pl1=rotate(-28,X)*pl;
      path3 pl2=rotate(-56,X)*pl;
      path3 pl3=shift(-0.3*normal(pl1))*pl1;

      triple[] asd=intersectionpoints(pl2,pl3);
      triple A=asd[1];
      triple B=asd[0];

      triple[] asf=intersectionpoints(pl,pl2);
      triple C=asf[1];
      triple D=asf[0];

      triple[] asg=intersectionpoints(pl,pl3);
      triple E=asg[1];
      triple F=asg[0];

      path3 q11=(D -- (-Y) -- (C-Y) -- C -- cycle);
      //surface sq11=surface(q11);
      //draw(sq11,yellow);//+opacity(.6));
      //draw(D -- -Y -- C-Y -- C--cycle);
      path3 q31=(D--C--A--B--cycle);
      face faces[];
      filldraw(faces.push(q11),project(q11),white+opacity(.5));
      filldraw(faces.push(q31),project(q31),white+opacity(.5));
      //draw(D--C--A--B--cycle,black+1bp);
      add(faces);

and the result is a vector graphic.

Vector graphic and 3D are very difficult to manage. With polygones it seems to be possible but needs some specific routines.