Shell script which parses .tex files for figures

Question

I would like to pull all figures including captions out of multiple .tex files and write them into a single new .tex file. This means I have to parse for

\begin{figure}
   . . . 
\end{figure}

and output that whole block. I have no clue about regular expressions, but I think grepor awkare best suited for this task. Can anyone help me out with the parsing-part? Writing a bash script to do the rest is no problem for me.

Answer 1

Edit: @deimi 's answer at Compile only the theorems using the xcomment package might make this awk script unnecessary.

Here's an awk solution that bypasses TeX parsing.

#!/usr/bin/awk
# Extract figure environments
#

BEGIN{
    printing = 0;
}

/begin\{figure/{
    printing = 1;
}

printing == 1 {
    print;
}

/end\{figure/{
    printing = 0;
}

Answer 2

My original answer was to be the following script, totally equivalent to the answer by Ethan Bolker, which posted when I was writing it.

/.*begin{figure}/{
    output=1
}
output==1{
    print
}
/.*end{figure}/{
    output=0
    print "% ---------------------------------- "
}

I cancelled my answer, but the OP asked me to post it nevertheless, so here it is.

In order to provide some added value, I'll post also the following variation, which deals with some rare cases (not really needed, I implemented it only for fun), in particular:

• It strips extraneous chars which could appear at the beginning of \begin{figure} or the end of \end{figure}
• It does not output figure environments inside verbatim, Verbatim or lstlisting.

BEGIN{
    in_verbatim=0
}
/.*begin.(verbatim|Verbatim|lstlisting)/{
    in_verbatim=1
}
/.*end.(verbatim|Verbatim|lstlisting)/{
    in_verbatim=0
}
/.*begin.figure./{
    if (! in_verbatim) {
        output=1
        split($0, aux, "begin{figure}")
        print "\\begin{figure}" aux[2]
    }
    next
}
/.*end.figure./{
    output=0
    if (! in_verbatim) {
       split($0, aux, "end{figure}")
       print aux[1] "end{figure}"
       print "% ---------------------------------- "
   }
}
output==1{
    print
}